home *** CD-ROM | disk | FTP | other *** search
/ Chip 2007 January, February, March & April / Chip-Cover-CD-2007-02.iso / Pakiet bezpieczenstwa / mini Pentoo LiveCD 2006.1 / mpentoo-2006.1.iso / livecd.squashfs / usr / share / aclocal / glibmm_check_perl.m4 < prev    next >
Encoding:
M4 Source File  |  2006-04-20  |  1.3 KB  |  55 lines
  1. dnl
  2. dnl Some macros needed for autoconf
  3. dnl
  4.  
  5.  
  6. ## GLIBMM_CV_PERL_VERSION(version)
  7. ##
  8. ## Helper macro of GLIBMM_CHECK_PERL().  It generates a cache variable
  9. ## name that includes the version number, in order to avoid clashes.
  10. ##
  11. AC_DEFUN([GLIBMM_CV_PERL_VERSION],[glibmm_cv_perl_version_[]m4_translit([$1],[.${}],[____])])
  12.  
  13.  
  14. ## GLIBMM_CHECK_PERL(version)
  15. ##
  16. ## Check for Perl >= version and set PERL_PATH.  If Perl is not found
  17. ## and maintainer-mode is enabled, abort with an error message.  If not
  18. ## in maintainer-mode, set PERL_PATH=perl on failure.
  19. ##
  20. AC_DEFUN([GLIBMM_CHECK_PERL],
  21. [
  22.   glibmm_perl_result=no
  23.  
  24.   AC_PATH_PROGS([PERL_PATH], [perl perl5], [not found])
  25.  
  26.   if test "x$PERL_PATH" != "xnot found"; then
  27.   {
  28.     AC_CACHE_CHECK(
  29.       [whether Perl is new enough],
  30.       GLIBMM_CV_PERL_VERSION([$1]),
  31.     [
  32.       ]GLIBMM_CV_PERL_VERSION([$1])[=no
  33.       "$PERL_PATH" -e "require v$1; exit 0;" >/dev/null 2>&1 && ]GLIBMM_CV_PERL_VERSION([$1])[=yes
  34.     ])
  35.     test "x${GLIBMM_CV_PERL_VERSION([$1])}" = xyes && glibmm_perl_result=yes
  36.   }
  37.   else
  38.   {
  39.     # Make sure we have something sensible, even if it doesn't work.
  40.     PERL_PATH=perl
  41.   }
  42.   fi
  43.  
  44.   if test "x$glibmm_perl_result" = xno && test "x$USE_MAINTAINER_MODE" = xyes; then
  45.   {
  46.     AC_MSG_ERROR([[
  47. *** Perl >= ]$1[ is required for building $PACKAGE in maintainer-mode.
  48. ]])
  49.   }
  50.   fi
  51.  
  52.   AC_SUBST([PERL_PATH])
  53. ])
  54.  
  55.